ALTER FRAGMENT

<оператор ALTER FRAGMENT> ::=

ALTER FRAGMENT ON <исходная таблица> <изменение фрагментации таблицы>
| ALTER FRAGMENT ON <исходный индекс> <изменние фрагментации индекса>

<исходная таблица> ::=

<имя таблицы>

<изменение фрагментации таблицы> ::=

<конструкция объединения>
| <конструкция отделения>
| <конструкция инициализации>
| <конструкция добавления фрагмента>
| <конструкция удаления фрагмента>
| <конструкция изменения условия фрагментации>

Примечание

<Исходная таблица> может упоминаться в качестве имени добавляемой таблицы только один раз.

<конструкция отделения> ::=

DETACH <имя пространства баз данных> <имя таблицы>

<конструкция инициализации> ::=

INIT [WITH ROWIDS] <способ фрагментации>

<способ фрагментации> ::=

FRAGMENT BY <конструкция фрагментации для таблиц>
| FRAGMENT BY <конструкция фрагментации для индексов>
| IN <имя пространства баз данных>
| IN <имя секции>

<конструкция фрагментации для таблиц> ::=

<циклическая фрагментация>
| <фрагментация по выражению>
| <фрагментация хешированием>
| <гибридная фрагментация>

<циклическая фрагментация> ::=

ROUND ROBIN <место назначения>

<место назначения> ::=

IN <имя пространства баз данных> {, <имя пространства баз данных>}
| IN <имя секции>

<фрагментация по выражению> ::=

EXPRESSION <список выражений фрагментации>
  [, REMAINDER IN <имя пространства баз данных>]

<список выражений фрагментации> ::=

<условие> IN <имя пространства баз данных>
  {, <условие> IN <имя пространства баз данных>}

<фрагментация хешированием> ::=

HASH (<имя столбца> {, <имя столбца>}) <место назначения>

<гибридная фрагментация> ::=

HYBRID (<имя столбца> {, <имя столбца>})
  <гибридная фрагментация по выражению>
| HYBRID ( HASH (<имя столбца> {, <имя столбца>}) )
  <гибридная фрагментация по выражению>

<гибридная фрагментация по выражению> ::=

EXPRESSION <список выражений гибридной фрагментации>
  [, REMAINDER IN <имя секции>]

<список выражений гибридной фрагментации> ::=

<условие> IN <имя секции> {, <условие> IN <имя секции>}

<конструкция фрагментации для индексов> ::=

<фрагментация по выражению>

<конструкция добавления фрагмента> ::=

ADD <имя пространства баз данных>
| ADD <условие> IN <имя пространства баз данных> [<позиция для добавления>]
| ADD REMAINDER IN <имя пространства баз данных>

<конструкция удаления фрагмента> ::=

DROP <имя пространства баз данных>

<конструкция изменения условия фрагментации> ::=

MODIFY <изменение фрагментации> {, <изменение фрагментации>}

<изменение фрагментации> ::=

<имя пространства баз данных> TO <условие> IN <имя пространства баз данных>
| <имя пространства баз данных> TO REMAINDER IN
  <имя пространства баз данных>

<исходный индекс> ::=

<имя индекса>

<изменение фрагментации индекса> ::=

<конструкция инициализации>
| <конструкция добавления фрагмента>
| <конструкция удаления фрагмента>
| <конструкция изменения условия фрагментации>